Base32?

_______________________________________________
vwnc mailing list
[hidden email]
http://lists.cs.uiuc.edu/mailman/listinfo/vwnc

"Boris Popov, DeepCove Labs"<[hidden email]> wrote:
> Is there a Base32 encoder/decoder readily available somewhere?

Not sure this will be terribly useful to you, but I got curious how much would the B32 implementation differ from the B64 one in Xtreams. This is a bit more straightforward implementation, possibly not the most efficient, but seems fairly readable to me. I'm having second thoughts on including the #isSeparator filtering directly in the encoding layer, it could be just as easily applied as a separate layer, giving the application more control over it.

ReadStream>>encodingBase32
        "Decodes characters of base-32 encoding into bytes. Ignores any intervening whitespace.
        Automatically ends the stream if it encounters final padding characters $=, or anything else that's not a valid encoding character."
        " ^<TransformReadStream>"
        "
                #('AE======' 'AEBA====' 'AEBAG===' 'AEBAGBA=' 'AEBAGBAFA')
                        collect: [ :each | each reading encodingBase32 rest ]
        "
        | map cache |
        map := [ :char | ('ABCDEFGHIJKLMNOPQRSTUVWXYZ234567' indexOf: char) - 1 ].
        cache := ByteString new: 8.
        ^(self transforming: [ :in :out || chars bits bytes i block nibble |
                        chars := [ (in rejecting: #isSeparator) read: 8 into: cache at: 1 ] on: Incomplete do: [ :incomplete | incomplete count ].
                        i := 1. bits := bytes := block := 0.
                        [ i > chars or: [ (nibble := map value: (cache at: i)) negative ]
                        ] whileFalse: [ block :=  (block bitShift: 5) + nibble. bits := bits + 5. i := i + 1 ].
                        [ bits > 7 ] whileTrue: [ bits := bits - 8. out put: ((block bitShift: bits negated) bitAnd: 255). bytes := bytes + 1 ].
                        bytes < 5 ifTrue: [ (Incomplete count: bytes) raise ] ]
        ) buffer: (RingBuffer on: (ByteArray new: 5));
                yourself


WriteStream>>encodingBase32
        "Encodes bytes into characters of base-32 encoding.
        Emits final padding characters ($=) as required, when the stream is closed."
        " ^<TransformWriteStream>"
        "
                (1 to: 5) collect: [ :i | String new writing encodingBase32 write: (ByteArray withAll: (1 to: i)); conclusion ]
        "
        | map cache |
        map := [ :i | 'ABCDEFGHIJKLMNOPQRSTUVWXYZ234567' at: i + 1 ].
        cache := ByteArray new: 5.
        ^(self transforming: [ :in :out || bytes chars bits block |
                        bytes := [ in read: 5 into: cache at: 1 ] on: Incomplete do: [ :incomplete | incomplete count ].
                        bytes isZero ifTrue: [ Incomplete zero raise ].
                        block := (1 to: bytes) inject: 0 into: [ :total :byte | (total bitShift: 8) + (cache at: byte)].
                        bits := bytes * 8.
                        [ bits > 0 ] whileTrue: [ bits := bits - 5. out put: (map value: ((block bitShift: bits negated) bitAnd: 31)) ].
                        chars := #[ 2 4 5 7 8 ] at: bytes.
                        chars < 8 ifTrue: [
                                8 - chars timesRepeat: [ out put: $= ].
                                (Incomplete count: bytes) raise ] ]
        ) buffer: (RingBuffer on: (ByteArray new: 5));
                yourself

_______________________________________________
vwnc mailing list
[hidden email]
http://lists.cs.uiuc.edu/mailman/listinfo/vwnc

Martin,

Ah, thanks for that. I was hoping there's some package somewhere that I
missed, but this should do as well, I'll give it a whirl. This won't be
for high performance application, so the implementation details are
irrelevant for as long as it produces the correct results.

-Boris

-----Original Message-----
From: [hidden email] [mailto:[hidden email]]
Sent: Monday, November 07, 2011 3:10 PM
To: Boris Popov, DeepCove Labs
Cc: [hidden email]
Subject: Re: [vwnc] Base32?

"Boris Popov, DeepCove Labs"<[hidden email]> wrote:
> Is there a Base32 encoder/decoder readily available somewhere?

Not sure this will be terribly useful to you, but I got curious how much
would the B32 implementation differ from the B64 one in Xtreams. This is
a bit more straightforward implementation, possibly not the most
efficient, but seems fairly readable to me. I'm having second thoughts
on including the #isSeparator filtering directly in the encoding layer,
it could be just as easily applied as a separate layer, giving the
application more control over it.

ReadStream>>encodingBase32
        "Decodes characters of base-32 encoding into bytes. Ignores any
intervening whitespace.
        Automatically ends the stream if it encounters final padding
characters $=, or anything else that's not a valid encoding character."
        " ^<TransformReadStream>"
        "
                #('AE======' 'AEBA====' 'AEBAG===' 'AEBAGBA='
'AEBAGBAFA')
                        collect: [ :each | each reading encodingBase32
rest ]
        "
        | map cache |
        map := [ :char | ('ABCDEFGHIJKLMNOPQRSTUVWXYZ234567' indexOf:
char) - 1 ].
        cache := ByteString new: 8.
        ^(self transforming: [ :in :out || chars bits bytes i block
nibble |
                        chars := [ (in rejecting: #isSeparator) read: 8
into: cache at: 1 ] on: Incomplete do: [ :incomplete | incomplete count
].
                        i := 1. bits := bytes := block := 0.
                        [ i > chars or: [ (nibble := map value:
(cache at: i)) negative ]
                        ] whileFalse: [ block :=  (block bitShift: 5) +
nibble. bits := bits + 5. i := i + 1 ].
                        [ bits > 7 ] whileTrue: [ bits := bits - 8. out
put: ((block bitShift: bits negated) bitAnd: 255). bytes := bytes + 1 ].

                        bytes < 5 ifTrue: [ (Incomplete count: bytes)
raise ] ]
        ) buffer: (RingBuffer on: (ByteArray new: 5));
                yourself


WriteStream>>encodingBase32
        "Encodes bytes into characters of base-32 encoding.
        Emits final padding characters ($=) as required, when the stream
is closed."
        " ^<TransformWriteStream>"
        "
                (1 to: 5) collect: [ :i | String new writing
encodingBase32 write: (ByteArray withAll: (1 to: i)); conclusion ]
        "
        | map cache |
        map := [ :i | 'ABCDEFGHIJKLMNOPQRSTUVWXYZ234567' at: i + 1 ].
        cache := ByteArray new: 5.
        ^(self transforming: [ :in :out || bytes chars bits block |
                        bytes := [ in read: 5 into: cache at: 1 ] on:
Incomplete do: [ :incomplete | incomplete count ].
                        bytes isZero ifTrue: [ Incomplete zero raise ].
                        block := (1 to: bytes) inject: 0 into: [ :total
:byte | (total bitShift: 8) + (cache at: byte)].
                        bits := bytes * 8.
                        [ bits > 0 ] whileTrue: [ bits := bits - 5. out
put: (map value: ((block bitShift: bits negated) bitAnd: 31)) ].
                        chars := #[ 2 4 5 7 8 ] at: bytes.
                        chars < 8 ifTrue: [
                                8 - chars timesRepeat: [ out put: $= ].
                                (Incomplete count: bytes) raise ] ]
        ) buffer: (RingBuffer on: (ByteArray new: 5));
                yourself

_______________________________________________
vwnc mailing list
[hidden email]
http://lists.cs.uiuc.edu/mailman/listinfo/vwnc

---

This message may contain confidential information and is intended for specific recipients unless explicitly noted otherwise. If you have reason to believe you are not an intended recipient of this message, please delete it and notify the sender. This message may not represent the opinion of IntercontinentalExchange, Inc. (ICE), its subsidiaries or affiliates, and does not constitute a contract or guarantee. Unencrypted electronic mail is not secure and the recipient of this message is expected to provide safeguards from viruses and pursue alternate means of communication where privacy or a binding message is desired.

_______________________________________________
vwnc mailing list
[hidden email]
http://lists.cs.uiuc.edu/mailman/listinfo/vwnc