Dolphin 6 with a black editor background?

Hi,

I set a black background throughout the editor. Now, everything looks
great but I can't see the cursor (as it is still black). How do I
change the color of the cursor to white?

Here are my current settings:

Workspace
        defaultBackcolor = black
        defaultFont = Lucida Console 12pt
        defaultTabWidth = 4
        textStyles
                argDecl = 255 196 196
                assignment = white
                binaryMessage = white bold
                binarySelector = white
                blockArgDecl = 255 196 196 italic bold
                braceHighlight = bright cyan
                braceMismatch = bright red, bold, underlined
                comment = bright green
                identifier = white
                illegal = bright red
                keywordMessage = white bold
                keywordSelector = white
                literalArray = white
                literalCharacter = bright yellow
                literalNumber = deep violet
                literalPseudo = bright cyan
                literalString = bright yellow
                literalSymbol = white
                normal = white
                specialCharacter = bright cyan
                tag = 0 128 255
                tempCloseBar = orange
                tempDecl = orange
                tempOpenBar = orange
                unaryMessage = white bold
                unarySelector = white

> Hi,
>
> I set a black background throughout the editor. Now, everything looks
> great but I can't see the cursor (as it is still black). How do I
> change the color of the cursor to white?

Is that an operating system controlled option, or is that something that can
be changed during mouse enter/leave events? I can't find anywhere that
suggests changing the colour of the I

Griff,

The caret color is an available option for the Scintilla view that we
use for the Dolphin workspaces. It's accessible via the #caretForecolor
aspect of ScintillaView. Unfortunately, this isn't currently exposed as
a User Preference for the development system.

I've recorded this as an enhancement request #2163 to be patched in the
next Live Update. Until that is released you can file in the following
patch code to gain access to the option.

Best regards

Andy Bower
Dolphin Support

--- snip
Presenter subclass: #SmalltalkWorkspace
        instanceVariableNames: 'evaluationContext errorModel findDetails
workspacePool evaluationPools compilationErrors textStyles
searchEnvironment modifiedModel flags'
        classVariableNames: 'Abbreviations AutoCompleteDwell AutoCompleteMask
DefaultBackcolor DefaultCaretColor DefaultFont DefaultTabWidth
IsAutoCompletionCaseInsensitive IsAutoCompletionEnabled
IsAutoCompletionSpaceAdded IsAutoCompletionTruncating
KeywordCompletions MaxAutoCompletionListSize StandardUnaryReturnTypes
TextStyles VariableTipsMask WordWrap'
        poolDictionaries: 'CompilerFlags ScintillaConstants'
        classInstanceVariableNames: 'additionalAccelerators
commandQueryHandlers'!

!SmalltalkWorkspace class methodsFor!

initialize
        "Private - Initialize the receiver's class variables.
                SmalltalkWorkspace initialize
        "

        self defaultBackcolor: (RGB
                                red: 250
                                green: 242
                                blue: 208).
        self defaultCaretColor: Color black.
        self defaultFont: (Font name: 'Arial' pointSize: 10).
        self wordWrap: true.
        self defaultTabWidth: 8.
        AutoCompleteDwell := 30.
        KeywordCompletions := self defaultKeywordCompletions.
        StandardUnaryReturnTypes := self defaultUnaryReturnTypes.
        IsAutoCompletionCaseInsensitive := false.
        IsAutoCompletionEnabled := true.
        IsAutoCompletionTruncating := false.
        IsAutoCompletionSpaceAdded := true.
        AutoCompleteMask := 1.
        VariableTipsMask := 2.
        MaxAutoCompletionListSize := 200! !
!SmalltalkWorkspace class categoriesFor:
#initialize!initializing!public! !

!SmalltalkWorkspace class methodsFor!

defaultCaretColor
        "Answer the default color to use for the caret in instances of the
receiver"

        ^DefaultCaretColor! !
!SmalltalkWorkspace class categoriesFor:
#defaultCaretColor!accessing!options!public! !
!SmalltalkWorkspace class methodsFor!

defaultCaretColor: aColorOrNil
        "Set the default caret color to use for instances of the receiver"

        DefaultCaretColor := aColorOrNil! !
!SmalltalkWorkspace class categoriesFor:
#defaultCaretColor:!accessing!options!public! !

!SmalltalkWorkspace methodsFor!

applyOptions
        "Private - Apply the class options to the receiver"

        view backcolor
                ifNotNil: [:color | color isDefault ifTrue: [view backcolor: self
class defaultBackcolor]].
        view font: self class actualFont.
        view wordWrap: self class wordWrap.
        view tabWidth: self class defaultTabWidth.
        view caretForecolor: self class defaultCaretColor.
        "textStyles are initialized to class setting by default, but parent
presenter might have
        replaced them. N.B. If you blow up here, its because you are trying to
use a non-Scintilla
        view with SmalltalkWorkspace. This is no longer supported."
        view textStyles: self textStyles.
        view wordChars: (Character byteCharacterSet
                                select: [:each | (Compiler isAValidIdentifierChar: each) or: [each
== $:]]).
        self hasSmalltalkStyler ifFalse: [self isAutoCompletionEnabled: false].
        view isAutoCompletionCaseInsensitive: self class
isAutoCompletionCaseInsensitive.
        "This has no effect, since we takeover insertion of the completed
word, but its a useful way to store the flag on a per-instance basis"
        view isAutoCompletionTruncating: self class isAutoCompletionTruncating.
        view maxCompletionListHeight: 10.
        view maxCompletionListWidth: 40.
        self areVariableTipsEnabled ifTrue: [view isBackgroundDwellEnabled:
true]! !
!SmalltalkWorkspace categoriesFor:
#applyOptions!operations!options!private! !
!SmalltalkWorkspace class methodsFor!

publishedAspects
        "Answer a <LookupTable> of the <Aspect>s published by the receiver."

        | answer |
        answer := super publishedAspects.
        #(#isAutoCompletionEnabled #isAutoCompletionCaseInsensitive
#isAutoCompletionTruncating)
                do: [:each | answer add: (Aspect boolean: each)].
        #(#defaultTabWidth #autoCompleteDwell #maxAutoCompletionListSize)
                do: [:each | answer add: (Aspect integer: each)].
        answer add: (Aspect color: #defaultCaretColor).
        ^answer
                add: (Aspect dictionary: #acceleratorKeyBindings) beImmutable;
                add: self textStylesAspect;
                yourself! !
!SmalltalkWorkspace class categoriesFor:
#publishedAspects!development!public! !

!SmalltalkWorkspaceDocument class methodsFor!

publishedAspects
        "Answer a <LookupTable> of the <Aspect>s published by the receiver."

        | answer |
        answer := super publishedAspects.
        #(#reuseIfOpen #canUseIdeaSpace #wordWrap #variableTips)
                do: [:each | answer add: (Aspect boolean: each)].
        answer
                add: (Aspect color: #defaultBackcolor);
                add: (Aspect color: #defaultCaretColor);
                add: (Aspect font: #defaultFont);
                add: (Aspect choice: #defaultView from: self resourceNames);
                add: (Aspect name: #defaultExtent);
                add: self workspaceClass textStylesAspect;
                add: (Aspect integer: #defaultTabWidth);
                yourself.
        ^answer! !
!SmalltalkWorkspaceDocument class categoriesFor:
#publishedAspects!development!public! !
!SmalltalkWorkspaceDocument class methodsFor!

defaultCaretColor
        "Answer the default caret color to use for instances of the receiver"

        ^self workspaceClass defaultCaretColor ! !
!SmalltalkWorkspaceDocument class categoriesFor:
#defaultCaretColor!accessing!options!public! !

!SmalltalkWorkspaceDocument class methodsFor!

defaultCaretColor: aColorOrNil
        "Set the default caret color to use for instances of the receiver"

        self workspaceClass defaultCaretColor: aColorOrNil! !
!SmalltalkWorkspaceDocument class categoriesFor:
#defaultCaretColor:!accessing!options!public! !


--- snip

Thanks Andy!