"Christopher J. Demers" <
[hidden email]> wrote in
message news:brtofs$78soc$
[hidden email]...
> Apparently the text portion of a ComboBox does not allow the user to enter
> more characters than can be displayed. I have found that the same issue
> exists with a TextEdit, and one can fix this by setting canHScroll to
true.
> I decided to be creative and try: "editView canHScroll: true", but alas
this
> does not work quite as I had hopped. See the code example bellow.
> ...
> I can get editView to return the TextEdit again if I change its id back to
> 1001. However it still does not behave like a proper ComboBox if a
> selection is made from the list, the text from the list never gets into
the
> real TextEdit. I suspect that the problem is it is destroyed and
recreated
> when the style is changed, and that disassociates it from the ComboBox.
> Has anyone else had to overcome this yet? Any pointers?
Yes, that would be the case. If you look at TextEdit>>canHScroll: you will
see that it is implemented in terms of View>>baseStyleMask:set:, and the
implementation of that is:
self baseStyleMask: anInteger set: aBoolean recreateIfChanged: true
i.e. the view will be recreated if the style is changed.
By default we recreate views when a style is changed as quite a lot of
Window styles cannot be changed once a window has been created. Normally
this recreation is transparent since the MVP framework will reinstate
everything as it was before. However recreating views that are not owned by
Dolphin (such as the edit box belonging to a combobox) is likely to break
things. Actually this is why the Visual Object Finder's option to find
external views is turned off by default - you can use it to inspect the
style settings,etc, of windows in other applications, but if you change
anything the other application will be toast.
In some cases we have taken the time to investigate whether recreation is
necessary, and you will see that the style modification method passes
'false' for the recreateIfChanged parameter. I can't remember whether we did
in this case (although the comment in MultilineTextEdit>>canHScroll: would
suggest we did), but taking a quick look now changing the style after view
recreation doesn't seem to have any effect, so recreating the edit control
when the style is changed would appear to be the only option. You can try it
yourself by inlining the send of #baseStyleMask:set: in
TextEdit>>canHScroll: and inverting the boolean argument.
Don't worry, though, there is a solution. We just need to extend ComboBox
itself to include a #canHScroll property like TextEdit's, since there is a
ComboBox style CBS_AUTOHSCROLL that corresponds to the Edit style
ES_AUTOHSCROLL. I've attached the code below. This enhancement will be
included in the next patch level.
Regards
Blair
--------------------------
"#1460"!
!ComboBox methodsFor!
canHScroll
"Answer whether the receiver's edit field is in horizontal scrolling mode."
^self baseStyleAllMask: CBS_AUTOHSCROLL! !
!ComboBox categoriesFor: #canHScroll!accessing-styles!public! !
!ComboBox methodsFor!
canHScroll: aBoolean
"Sets the receiver into horizontal scrolling mode if aBoolean is true. When
this style is
off the control limits the amount of text that can be entered to that which
can be displayed
in the box. When the style is on the user can enter more text than can be
displayed (the
caret remains at the right edge of the field and the text scrolls left to
accomodate new
input)."
"Implementation Note: The control ignores changes to this style after
creation, so we must
accept the default action, which is to recreate the view."
self baseStyleMask: CBS_AUTOHSCROLL set: aBoolean! !
!ComboBox categoriesFor: #canHScroll:!accessing-styles!public! !
!ComboBox class methodsFor!
publishedAspectsOfInstances
"Answer a <LookupTable> of the <Aspect>s published by instances of the
receiver."
^(super publishedAspectsOfInstances)
add: (Aspect integer: #droppedHeight);
add: (Aspect choice: #mode from: Modes);
add: (Aspect boolean: #canHScroll);
yourself! !
!ComboBox class categoriesFor:
#publishedAspectsOfInstances!constants!development!public! !
Locked
