[VW 7.5] Hypertext linking to Web Browser

Hi Travis,

Thanks for this detailed description of the RB hypertexting.

Since I posted, I’ve managed to integrate the VWHelp hypertext into my own text displays (you can edit too).

It was “relatively” straightforward, once I’d figured out the framework (see below).

Another testament to Wrapper and the Arbor framework, or is it ugly hacking?

Whatever, it works.

There’s only one problem - why does my colorBlue show up as yellow on the MacOSX?

Cheers,

Stewart

============================================================================================

For anyone that’s interested… it started with introducing a new Spec - VWHelp.HypertextEditorSpec (sub class of UI.TextEditorSpec)

This class has one method:

dispatchTo: policy with: builder

            "Added to enable plugging in of hypertext functionality."

            policy

                        textView: self

                        into: builder

                        view: AHSHelpTextEditorView new

                        controller: VWHelp.AHSHelpTextEditorController new

The LookPolicy method is a hack the existing textView: spec into: builder

textView: spec into: builder view: aView controller: aController

            "Added to enable plugging in of hypertext functionality. 22/08/07 SIM."

            | model component menu performer alignment style |

            model := spec modelInBuilder: builder.

            component := aView class model: model.

            component controller: aController.

            Etc.

To enable hypertext use this spec in your windowSpec. Beware, this is a manual edit of the generated UI builder code!

Then in my model class add these items to an appropriate menu:

menu addItem:

                        ((MenuItem labeled: 'Hypertext')

                                    nameKey: #hypertext;

                                    value: [: aHelpTextEditorController | self createLinkFor: aHelpTextEditorController).

            menu addItem:

                        ((MenuItem labeled: 'Remove Hypertext')

                                    nameKey: #removeHypertext;

                                    value: [: aHelpTextEditorController | self removeLinkFor: aHelpTextEditorController]).

Add the callbacks in the model:

createLinkFor: aController

            "Create a hypertext link for the current selection on aController.

            If there is already an existing link, get the current uri and present that to the user for modification."

            | displayString uri currentUri existingLink |

            displayString := aController selection ifEmpty: [^self].

            currentUri := (aController trackTextPosition: (self attributeAt: 'popupMenuPoint' ifAbsent: [0@0]))

                        ifNotNil: [: value | value firstAvailableLink ifNotNil: [: link | (existingLink := link) linkObject] ifNil: ['']].

            (uri := Dialog

                        request: ('Please enter the Uri to be linked with <1s>' with: displayString)

                        initialAnswer: currentUri) ifEmpty: [^self].

            self

                        removeLinkFor: aController;

                        addEmphasis:

                                    (ArborHyperlinkAssociation

                                                value: (URIHyperlinkObject new linkObject: uri))

removeLinkFor: aController

            | selectedText |

            selectedText := aController selection.

            selectedText removeAllHyperLinks.

            aController

                        replaceSelectionWith: selectedText;

                        accept.

            self changed: #linkRemoved.

            aController restoreSelection

within postOpen…

            self

                        widget: #text

                        when: #popupMenuCreated

                        send: #aboutToPopupMenu

                        to: self

aboutToPopupMenu

            "Take note of the location of the cursor as the menu popping up.

            This is used later to access the underlying link."

            self

                        attributeAt: 'popupMenuPoint'

                        put: (self widgetAt: #text) controller sensor cursorPoint

and finally, the point of the whole thing:

engageURIHyperlink: aLink

            self openWebBrowserOn: aLink linkObject

For completeness, URIHyperlinkObject is a new subclass of VWHelp.ArborHyperlink with:

engageFor: anObject

            "The hyperlink has been engaged within the context of anObject."

            ^anObject engageURIHyperlink: self

with the emphasis methods overloaded.