[vwnc] Exception comparing LargeNegativeInteger to Float

Björn, you can probably reuse the integer implementation of sqrtFloor to implement FixedPoint>>sqrt.  Something along the lines of...

FixedPoint>>sqrt

 sqrtValue := ("self integerValue" * (10 ** (self scale * 2))) sqrtFloor.
 "now sqrtValue has self integerValue sqrtFloor with self scale digit's worth of precision, so create the answer for that"

See also Integer>>sqrtRounded for a simpler application of the same principle.

Andres.

-----Original Message-----
From: [hidden email] [mailto:[hidden email]] On Behalf Of Björn Eiderbäck
Sent: Wednesday, July 01, 2009 3:38 PM
To: Raymond, Terry
Cc: VWNC
Subject: Re: [vwnc] Exception comparing LargeNegativeInteger to Float

In a similar realm is:
Why don't fixed points implement sqrt?
E.g. 3s100 sqrt  => 1.73205

But if one implements (maybe it could be implemented more effectively but a simple Newton-Raphson could be implemented in a few minutes):
FixedPoint>>sqrt
    "Answer the square root of the receiver."

    | xn xold lim |
    xn := super sqrt asFixedPoint: scale.
    xold := self.
    lim := (10 ** xn scale) reciprocal.
    [(xold - xn) abs > lim] whileTrue:
            [xold := xn.
            xn := (xn + (self / xn)) / 2].
    ^xn

the result is
1.7320508075688772935274463415058723669428052538103806280558069794519330169088000370811461867572485757s.

And why not add
FixedPoint class>>pi: numberOfDecimals

    ^(0 to: numberOfDecimals)
        inject: (0 asFixedPoint: numberOfDecimals)
        into:
            [:s :k |
            | p |
            p := 8 * k.
            s
                +
                    ((4 / (p + 1) - (2 / (p + 4)) - (1 / (p + 5)) - (1 / (p + 6))) / (16 ** k))]

Example:
FixedPoint pi: 100
3.1415926535897932384626433832795028841971693993751058209749445923078164062862089986280348253421170680s

I mean that it would be really nice if arithmetic and mathematical functions were improved a little and return expected results (as returning a fixed point when taking the square root of one). Especially since one could improve a lot by quite simple means, to a great extent thanks to the already present type hierarchy which enable simple improvements on an per type level.

Cheers,
Björn

Extra: if you really want a multitude of decimals to pi try this:
| k a b a1 b1 |
k := 2. a := 4. b := 1. a1 := 12. b1 := 4.
[true]
    whileTrue:
        [| p q d d1 a1Old b1Old |
        p := k * k. q := 2 * k + 1. k := k + 1. a1Old := a1. b1Old := b1.
        a1 := p * a + (q * a1). b1 := p * b + (q * b1). a := a1Old. b := b1Old.
        d := a // b. d1 := a1 // b1.
        [d == d1]
            whileTrue:
                [Transcript print: d.
                a := 10 * (a \\ b). a1 := 10 * (a1 \\ b1).
                d := a // b. d1 := a1 // b1]]

On 2009-07-01 17:52, Terry Raymond wrote:
> Hi
>
> The following generates an exception.
> 10.0<  -1100000000000000000000000000000000000000
>
> This is because Integer implements #lessFromFloat: as
>
> ^aFloat<  self asFloat
>
> and -1100000000000000000000000000000000000000 cannot be converted to a Float.
>
> However, an alternative implementation for large integer will work and
> executes faster, it is slower for small integer.
>
> ^aFloat floor<  self
>
> Terry
>
> ===========================================================
> Terry Raymond
> Crafted Smalltalk
> 80 Lazywood Ln.
> Tiverton, RI  02878
> (401) 624-4517      [hidden email]
> <http://www.craftedsmalltalk.com>
> ===========================================================
>
>
> _______________________________________________
> vwnc mailing list
> [hidden email]
> http://lists.cs.uiuc.edu/mailman/listinfo/vwnc
>
_______________________________________________
vwnc mailing list
[hidden email]
http://lists.cs.uiuc.edu/mailman/listinfo/vwnc

_______________________________________________
vwnc mailing list
[hidden email]
http://lists.cs.uiuc.edu/mailman/listinfo/vwnc