The Inbox: Monticello-ct.734.mcz

A new version of Monticello was added to project The Inbox:
http://source.squeak.org/inbox/Monticello-ct.734.mcz

==================== Summary ====================

Name: Monticello-ct.734
Author: ct
Time: 28 December 2020, 12:48:47.150654 pm
UUID: 3964a938-941a-4e1a-89e6-d1b33e370e29
Ancestors: Monticello-mt.733

Proposal: Dispatch request notifications via ToolSet before opening an interactive dialog window. This should give us better feedback in non-interactive environments such as CI jobs or production contexts (at the moment, CI only hangs silently).

Questions: Is it okay to depend on the System, Tools, and CommandLineTools from Monticello? Are there further exceptions that should be dispatched equally?

=============== Diff against Monticello-mt.733 ===============

Item was added:
+ ----- Method: CommandLineToolSet class>>mcHandleChangeSelectionRequest: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleChangeSelectionRequest: aNotification
+
+ ^ self handleError: aNotification!

Item was added:
+ ----- Method: CommandLineToolSet class>>mcHandleMergeResolutionRequest: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleMergeResolutionRequest: aNotification
+
+ ^ self handleError: aNotification!

Item was added:
+ ----- Method: CommandLineToolSet class>>mcHandleNoChangesNotification: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleNoChangesNotification: aNotification
+
+ ^ self handleWarning: aNotification!

Item was added:
+ ----- Method: CommandLineToolSet class>>mcHandleSaveVersionRequest: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleSaveVersionRequest: aNotification
+
+ ^ self handleError: aNotification!

Item was changed:
  ----- Method: MCChangeSelectionRequest>>defaultAction (in category 'handling') -----
  defaultAction
+
+ ^ ToolSet mcHandleChangeSelectionRequest: self!
- ^ (MCChangeSelector forPatch: patch)
- label: label ;
- showModally!

Item was changed:
  ----- Method: MCMergeResolutionRequest>>defaultAction (in category 'handling') -----
  defaultAction
+
+ ^ ToolSet mcHandleMergeResolutionRequest: self!
- ^ (MCMergeBrowser new
- merger: merger;
- label: messageText) showModally!

Item was changed:
  ----- Method: MCNoChangesException>>defaultAction (in category 'handling') -----
  defaultAction
+
+ ^ ToolSet mcHandleNoChangesNotification: self!
- self inform: 'No changes'!

Item was changed:
  ----- Method: MCVersionNameAndMessageRequest>>defaultAction (in category 'handling') -----
  defaultAction
+
+ ^ ToolSet mcHandleSaveVersionRequest: self!
- ^ MCSaveVersionDialog new
- versionName: suggestion;
- logMessage: initialMessage;
- patchBlock: patchBlock;
- selection: 1;
- showModally!

Item was added:
+ ----- Method: StandardToolSet class>>mcHandleChangeSelectionRequest: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleChangeSelectionRequest: aNotification
+
+ ^ (MCChangeSelector forPatch: aNotification patch)
+ label: aNotification label;
+ showModally!

Item was added:
+ ----- Method: StandardToolSet class>>mcHandleMergeResolutionRequest: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleMergeResolutionRequest: aNotification
+
+ ^ (MCMergeBrowser new
+ merger: aNotification merger;
+ label: aNotification messageText) showModally!

Item was added:
+ ----- Method: StandardToolSet class>>mcHandleNoChangesNotification: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleNoChangesNotification: aNotification
+
+ ^ self inform: 'No changes' translated!

Item was added:
+ ----- Method: StandardToolSet class>>mcHandleSaveVersionRequest: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleSaveVersionRequest: aNotification
+
+ ^ MCSaveVersionDialog new
+ versionName: aNotification suggestedName;
+ logMessage: aNotification initialMessage;
+ patchBlock: aNotification patchBlock;
+ selection: 1;
+ showModally!

Item was added:
+ ----- Method: ToolSet class>>mcHandleChangeSelectionRequest: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleChangeSelectionRequest: aNotification
+
+ ^ self default
+ ifNil: [self handleError: aNotification]
+ ifNotNil: [:ts | ts mcHandleChangeSelectionRequest: aNotification]!

Item was added:
+ ----- Method: ToolSet class>>mcHandleMergeResolutionRequest: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleMergeResolutionRequest: aNotification
+
+ ^ self default
+ ifNil: [self handleError: aNotification]
+ ifNotNil: [:ts | ts mcHandleMergeResolutionRequest: aNotification]!

Item was added:
+ ----- Method: ToolSet class>>mcHandleNoChangesNotification: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleNoChangesNotification: aNotification
+
+ ^ self default
+ ifNil: [self handleWarning: aNotification]
+ ifNotNil: [:ts | ts mcHandleNoChangesNotification: aNotification]!

Item was added:
+ ----- Method: ToolSet class>>mcHandleSaveVersionRequest: (in category '*Monticello-Versioning-handlers') -----
+ mcHandleSaveVersionRequest: aNotification
+
+ ^ self default
+ ifNil: [self handleError: aNotification]
+ ifNotNil: [:ts | ts mcHandleSaveVersionRequest: aNotification]!