The Inbox: ProtocolsTests-fbs.1.mcz

A new version of ProtocolsTests was added to project The Inbox:
http://source.squeak.org/inbox/ProtocolsTests-fbs.1.mcz

==================== Summary ====================

Name: ProtocolsTests-fbs.1
Author: fbs
Time: 23 March 2011, 10:13:32.761 pm
UUID: 60d34548-1480-8649-815c-5604e70b6857
Ancestors:

ProtocolBrowser, Lexicon aren't in Tools-Browser but in Protocols-Tools, so their tests belong in the ProtocolsTests package.

==================== Snapshot ====================

SystemOrganization addCategory: #ProtocolsTests!

TestCase subclass: #LexiconTest
        instanceVariableNames: 'browser'
        classVariableNames: ''
        poolDictionaries: ''
        category: 'ProtocolsTests'!

----- Method: LexiconTest>>setUp (in category 'as yet unclassified') -----
setUp
        browser := Lexicon new openOnClass: Lexicon showingSelector: Lexicon allSelectors asOrderedCollection first.!

----- Method: LexiconTest>>tearDown (in category 'as yet unclassified') -----
tearDown
        ToolBuilder default close: browser topView.!

----- Method: LexiconTest>>testLastSearchString (in category 'as yet unclassified') -----
testLastSearchString
        | longestName |
        browser lastSearchString: 'No selector includes this in its name, I''ll bet!!'.
        self assert: browser messageList isEmpty.
       
        browser lastSearchString: ''.
        self deny: browser messageList isEmpty.
       
        longestName := (browser class allSelectors asOrderedCollection sort: [:a :b | a size < b size]) last.
        browser lastSearchString: longestName.
        self assert: browser messageList size = 1.!

----- Method: LexiconTest>>testOpenFullProtocolForClass (in category 'as yet unclassified') -----
testOpenFullProtocolForClass
        | l |
        l := (Lexicon openFullProtocolForClass: Lexicon).
        [self assert: (l isKindOf: ProtocolBrowser)] "No, really!!"
                ensure: [ ToolBuilder default close: l topView ].!

----- Method: LexiconTest>>testSelectCategoryListIndex (in category 'as yet unclassified') -----
testSelectCategoryListIndex
        browser categoryListIndex: 0.
        browser messageListIndex: 1.
        self assert: browser categoryListIndex = 0.
        self deny: browser hasMessageSelected.
       
        browser categoryListIndex: 1.
        browser messageListIndex: 1.
        self assert: browser categoryListIndex = 1.
        self assert: browser hasMessageSelected.
        self assert: browser messageListIndex = 1.!

TestCase subclass: #ProtocolBrowserTest
        instanceVariableNames: ''
        classVariableNames: ''
        poolDictionaries: ''
        category: 'ProtocolsTests'!

----- Method: ProtocolBrowserTest>>testOpenFullProtocolForClass (in category 'as yet unclassified') -----
testOpenFullProtocolForClass
        | pb |
        pb := (ProtocolBrowser openFullProtocolForClass: ProtocolBrowser).
        [self assert: (pb isKindOf: ProtocolBrowser)]
                ensure: [ ToolBuilder default close: pb topView ].!

----- Method: ProtocolBrowserTest>>testOpenSubProtocolForClass (in category 'as yet unclassified') -----
testOpenSubProtocolForClass
        | pb |
        pb := (ProtocolBrowser openSubProtocolForClass: ProtocolBrowser).
        [self assert: (pb isKindOf: ProtocolBrowser)]
                ensure: [ ToolBuilder default close: pb topView ].!